Re: В zsh не работает alias
Dmitry-T -> debian-russian@lists.debian.org @ Tue, 1 Mar 2005 13:43:41 +0400:
>> D> В файле .zshrc есть например:
>>
>> D> alias ll='ls -l'
>> D> alias la='ls -A'
>>
>> D> но если я в командной строке набираю ll, то получаю
>>
>> D> zsh: command not found: ll
>>
>> D> тоже для любого алиаса. Если беру .zshrc из /usr/share/doc/zsh/examples
>> D> без изменений, то таже история. Может нужны какие-то опции или набирать
>> D> как-то особенно?
>>
>> А это точно ~/.zshrc? Ну и, понятно, после редактирования его уже
>> запущенные шеллы сами по себе его не заметят.
D> Я даже перезагружался - без результата, а вот формат подсказки из этого же
D> ~/.zshrc работает нормально :(
D> Вообще я правильно понимаю, что если в ~/.zshrc есть строчка
D> alias ll='ls -l'
D> то я в командной строке могу набирать ll и должен получать после <enter>
D> ls -l?
Нет, ты должен получать результат выполнения ls -l.
D> Может кто-нибудь кинет рабочий zshrc и номер версии zsh?
Легко, но если ты в нем застрелишься - пеняй на себя.
----------------------------------------------------------------
# For /etc/zshrc
# > doesn't overwrite existing files and >> doesn't create new
setopt no_clobber
# verify history references before execution
setopt hist_verify
# wait 10 seconds before
setopt rm_star_wait
# For ~/.zshrc
# directory in command position is implicit cd
setopt auto_cd
# don't automatically use menu completion on second TAB
setopt no_auto_menu
# cd pushes old directory onto stack
setopt auto_pushd
# complete in cursor position
setopt complete_in_word
# use extended globbing patterns
setopt extended_glob
# write timestamps and duration of commands into history
setopt extended_history
# don't beep on attempt to refer non-existent history event
setopt no_hist_beep
# ignore all duplicates in history
setopt hist_ignore_all_dups
# remove from history command lines starting with space
setopt hist_ignore_space
# remove history commands from history
setopt hist_no_store
# remove superfluous blanks from history
setopt hist_reduce_blanks
# don't beep on ambiguous completions
setopt no_list_beep
# use columns with different widths to keep list smaller
setopt list_packed
# list jobs in long format
setopt long_list_jobs
# numeric filenames are sorted numerically
setopt numeric_glob_sort
# ignore dups in pushd
setopt pushd_ignore_dups
# '' inside '-quoted string means '
setopt rc_quotes
# share history between shells
setopt share_history
# word-motion commands do not treat / as a part of a word
slashre=/; WORDCHARS=${WORDCHARS/$slashre}
alias 0='sudo '
case $OSTYPE in
linux*)
alias ls='ls -AF --color=auto'
psname () { ps -fC $1 }
alias pkill=killall
;;
*)
alias ls='ls -AF'
psname () { ps -fe | awk "\$8 ~ /($1|CMD)\$/ {print}" }
;;
esac
alias xps='ps -efl | fgrep -v fgrep | fgrep'
alias ll='ls -ali'
alias x+="chmod a+x"
alias bc="bc -q"
alias md="mkdir -p"
alias sshag="exec ssh-agent zsh -l"
alias scr="screen -D -RR"
alias fls="tail -f /var/log/syslog"
alias mwho='[[ -f /var/lock/LCK..modem ]] && ps -fwp `cat /var/lock/LCK..modem`'
alias voice='[[ ! -f /var/lock/LCK..modem ]] && echo voice >/var/lock/LCK..modem'
alias novoice='[[ -f /var/lock/LCK..modem ]] && grep -q voice /var/lock/LCK..modem && rm /var/lock/LCK..modem'
alias pksr="apt-cache search"
alias pksh="apt-cache show"
alias pksrnm="pksr --names-only"
alias pkdep="apt-cache depends"
alias pkin="apt-mget install"
alias pkrm="apt-mget remove"
alias pksrc="apt-mget source"
alias cpu="sudo toshset -cpu"
alias xtermk="LANG=ru_RU.KOI8-R RESOURCE_NAME=KOI xterm"
alias xtermw="LANG=ru_RU.CP1251 RESOURCE_NAME=WIN xterm"
alias xtermi="LANG=ru_RU.ISO8859-5 RESOURCE_NAME=ISO xterm"
alias xtermu="LANG=ru_RU.UTF-8 RESOURCE_NAME=UTF xterm -u8"
alias edt="emacsclient --no-wait"
# to smooth work of triple-click
alias ${SHELL:t}`print -nP '%#'`=
[[ -e ~/.smbauth ]] && alias smbclient="smbclient -A ~/.smbauth"
autoload -U compinit
compinit
compdef _apt apt-mget=apt-get
autoload zmv
autoload mere
autoload edit-command-line
zle -N edit-command-line
CHARSET=`locale charmap`
case $TERM in
xterm*|rxvt*)
function precmd { print -nP "\033]2; $CHARSET:zsh@%m:%~%# \007\033]1;%m:%~%#\007" }
function preexec { print -nP "\033]2; $CHARSET:zsh@%m:%~%# $2\007\033]1;%m:%~%# $2\007" }
;;
screen)
alias vim='vim -X '
local propmt_tt_addition='%S[]%s'
;;
esac
case $TERM in
dumb)
PROMPT="%#"
;;
*)
PROMPT="%B${propmt_tt_addition}%*%b %(!.%S.)%n@%M%(!.%s.):%~ %(?..?%B%?%b)
%B${SHELL:t}%#%b "
;;
esac
HISTSIZE=1000
SAVEHIST=1000
HISTFILE=~/.zhistory
REPORTTIME=30
READNULLCMD=less
HELPDIR=/usr/share/zsh/help
[[ $TERM == xterm* || $TERM == rxvt* ]] || function x11 { if [[ -z "$1" ]]; then startx; else X -query "$1"; fi; logout }
[[ $TERM == xterm* || $TERM == rxvt* ]] || function x12 { if [[ -z "$1" ]]; then startx -- -layout extmouse; else X -query "$1" -layout extmouse; fi; logout }
bindkey -e
if [[ "$TERM" != emacs ]]; then
bindkey '\ev' edit-command-line
[[ -z "$terminfo[kf1]" ]] || bindkey -M emacs "$terminfo[kf1]" run-help
fi
----------------------------------------------------------------
zsh 4.2.4 (i686-pc-linux-gnu)
zsh 4.0.4 (i686-pc-linux-gnu)
zsh 4.0.7 (sparc-sun-solaris2.8)
zsh 4.0.7 (i386-pc-solaris2.8)
zsh 4.2.0 (i386-portbld-freebsd4.8)
zsh 4.2.1 (amd64-portbld-freebsd5.3)
и так далее.
--
Artem Chuprina
RFC2822: <ran{}ran.pp.ru> Jabber: ran@jabber.ran.pp.ru
Reply to: