Re: Collegare una Fotocamera USB

[Gothormr <Gothormr@yahoo.it>]

On Tue, Sep 16, 2003 at 04:17:37PM +0200, Michele Costantino wrote:
[...]
> quello che dovrebbe essere su sda1
[...]

Anche la mia macchina è vista come un'unità scsi, sotto windows è vista come hd rimovibile. Sinceramente non so se ti possa essere utile, ma per connetterla a linux ho realizzato questo semplice script. Ovviamente dovrai modificarlo in base alle tue esigenze, comunque spero ti possa essere d'aiuto.

saluti

fabio

#!/bin/csh
set LOG_FILE="/var/log/olympus.log"	# file per il log delle operazioni

				# opzioni per il mount della fotocamera #
set MOUNT_OPT="umask=027,uid=foto,gid=foto"	# opzioni mount
set MOUNT_DEV="/dev/sda1"	# dispositivo da montare
set MOUNT_FS="vfat"		# tipo di filesystem
set MOUNT_MP="/mnt/olympus"	# mount point

				# opzioni per i moduli da caricare #
set USB_CONTROLLER="usb-ohci"	# modulo per il controller USB
set USB_STORAGE="usb-storage"	# modulo per periferiche di memorizzazione USB
set SD="sd_mod"			# modulo dischi scsi	
set TIMEOUT="1"			# tempo di attesa tra il caricamento di un
							# modulo e l'altro

echo "Controlla che la macchina sia accesa, premi invio per continuare..."
$<

echo -n "Carico i moduli necessari al kernel... $USB_CONTROLLER"
if ( ! { ( modprobe $USB_CONTROLLER >& $LOG_FILE ) } ) then
	echo "-> errore!"
	echo "Controlla $LOG_FILE per dettagli."
	exit
endif

sleep $TIMEOUT

echo -n " $USB_STORAGE"
if ( ! { ( modprobe $USB_STORAGE >>& $LOG_FILE ) } ) then
	echo "-> errore!"
	echo "Controlla $LOG_FILE per dettagli."
	echo -n "Rimuovo i moduli già caricati... $USB_CONTROLLER"
	if ( ! { ( modprobe -r $USB_CONTROLLER >>& $LOG_FILE) } ) then
		echo "-> errore!"
		echo "Controlla $LOG_FILE per dettagli."
		exit
	endif
	echo "."
	exit
endif

sleep $TIMEOUT

echo -n " $SD"
if ( ! { ( modprobe $SD >>& $LOG_FILE ) } ) then
	echo "-> errore!"
	echo "Controlla $LOG_FILE per dettagli."
	echo -n "Rimuovo i moduli già caricati... $USB_STORAGE"
	if ( ! { ( modprobe -r $USB_STORAGE >>& $LOG_FILE) } ) then
		echo "-> errore!"
		echo "Controlla $LOG_FILE per dettagli."
		echo -n "Rimuovo i moduli già caricati..."
	endif
	echo -n "USB_CONTROLLER"
	if ( ! { ( modprobe -r $USB_CONTROLLER >>& $LOG_FILE) } ) then
		echo "-> errore!"
		echo "Controlla $LOG_FILE per dettagli."
		exit
	endif
	echo "."
	exit
endif

echo "."

echo -n "Monto la fotocamera..."
if ( { (mount -t $MOUNT_FS -o $MOUNT_OPT $MOUNT_DEV $MOUNT_MP >>& $LOG_FILE) } ) then
	echo " fatto."
else
	echo "-> errore!"
	echo "Controlla $LOG_FILE per dettagli."
	echo -n "Rimuovo i moduli... $SD"
	if ( ! { ( modprobe -r $SD >>& $LOG_FILE ) } ) then
		echo "-> errore!"
		echo "Controlla $LOG_FILE per dettagli."
		echo -n "Rimuovo i moduli..."
	endif
	echo -n " $USB_STORAGE"
	if ( ! { ( modprobe -r $USB_STORAGE >>& $LOG_FILE) } ) then
		echo "-> errore!"
		echo "Controlla $LOG_FILE per dettagli."
		echo -n "Rimuovo i moduli..."
	endif
	echo -n " $USB_CONTROLLER"
	if ( ! { ( modprobe -r $USB_CONTROLLER >>& $LOG_FILE) } ) then
		echo "-> errore!"
		echo "Controlla $LOG_FILE per dettagli."
		exit
	endif
	echo "."
	exit
endif
echo "La fotocamera è montata; dopo aver scaricato le foto,"
echo "premi invio per smontarla..."
$<
echo -n "Smonto la macchina..."
if ( { ( umount /dev/sda1 >>& $LOG_FILE ) } ) then
	echo " fatto."
else 
	echo "-> errore!"
	echo "Controlla $LOG_FILE per dettagli."
endif

echo -n "Rimuovo i moduli... $SD"
if ( ! { ( modprobe -r $SD >>& $LOG_FILE ) } ) then
	echo "-> errore!"
	echo "Controlla $LOG_FILE per dettagli."
	echo -n "Rimuovo i moduli..."
endif
echo -n " $USB_STORAGE"
if ( ! { ( modprobe -r $USB_STORAGE >>& $LOG_FILE) } ) then
	echo "-> errore!"
	echo "Controlla $LOG_FILE per dettagli."
	echo -n "Rimuovo i moduli..."
endif
echo -n " $USB_CONTROLLER"
if ( ! { ( modprobe -r $USB_CONTROLLER >>& $LOG_FILE) } ) then
	echo "-> errore!"
	echo "Controlla $LOG_FILE per dettagli."
	exit
endif
echo "."
echo "Ricorda di spegnere la macchina :)="

-- 
Computers are like air conditioners:
they stop working properly when you open Windows...