Can't get ethereal to compile with IPv6 support
Hi,
I'm the maintainer of ethereal and can't get it to enable ipv6-support.
The configure script can't get ipv6 stack type and I have a hard time
figuring how it determines this. The relevant code is attached.
I tried to force the stack type to 'linux' but it failed to link (to
libsnmp!).
Frederic
[PS: I'm not on the list; please CC answers]
--
Frederic Peters <fpeters@tiscalinet.be> « Le travail a été ce que l'homme
Debian GNU/Linux: http://www.debian.org a trouvé de mieux pour ne rien
Gaby: http://gaby.sourceforge.net faire de sa vie. » R. Vaneigem
#
# AC_ETHEREAL_IPV6_STACK
#
# By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
#
AC_DEFUN(AC_ETHEREAL_IPV6_STACK,
[
v6type=unknown
v6lib=none
AC_MSG_CHECKING([ipv6 stack type])
for i in v6d toshiba kame inria zeta linux; do
case $i in
v6d)
AC_EGREP_CPP(yes, [dnl
#include </usr/local/v6/include/sys/types.h>
#ifdef __V6D__
yes
#endif],
[v6type=$i; v6lib=v6;
v6libdir=/usr/local/v6/lib;
CFLAGS="-I/usr/local/v6/include $CFLAGS"])
;;
toshiba)
AC_EGREP_CPP(yes, [dnl
#include <sys/param.h>
#ifdef _TOSHIBA_INET6
yes
#endif],
[v6type=$i; v6lib=inet6;
v6libdir=/usr/local/v6/lib;
CFLAGS="-DINET6 $CFLAGS"])
;;
kame)
AC_EGREP_CPP(yes, [dnl
#include <netinet/in.h>
#ifdef __KAME__
yes
#endif],
[v6type=$i; v6lib=inet6;
v6libdir=/usr/local/v6/lib;
CFLAGS="-DINET6 $CFLAGS"])
;;
inria)
AC_EGREP_CPP(yes, [dnl
#include <netinet/in.h>
#ifdef IPV6_INRIA_VERSION
yes
#endif],
[v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
;;
zeta)
AC_EGREP_CPP(yes, [dnl
#include <sys/param.h>
#ifdef _ZETA_MINAMI_INET6
yes
#endif],
[v6type=$i; v6lib=inet6;
v6libdir=/usr/local/v6/lib;
CFLAGS="-DINET6 $CFLAGS"])
;;
linux)
if test -d /usr/inet6; then
v6type=$i
v6lib=inet6
v6libdir=/usr/inet6
CFLAGS="-DINET6 $CFLAGS"
fi
;;
esac
if test "$v6type" != "unknown"; then
break
fi
done
if test "$v6lib" != "none"; then
for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
if test -d $dir -a -f $dir/lib$v6lib.a; then
LIBS="-L$dir $LIBS -l$v6lib"
break
fi
done
enable_ipv6="yes"
else
enable_ipv6="no"
fi
AC_MSG_RESULT(["$v6type, $v6lib"])
])
Reply to: